これは、コマンドプロンプト(cmd.exe) Advent Calendar 2015 - Qiitaの24日目の記事です。※Windows 10 Home 64bit 搭載のcmd.exeにて検証を行っています。
さて今回は、所属している同人ゲームサークル「月うさぎプロジェクト：同人ゲームサークル」の最新作「THREE FORKS」で使用していたビルドスクリプトを公開します。

構成

構成は以下のとおり。

  • @ビルド＆リリース.bat
    • ビルド用BATです。このBATを叩きます。
  • @ビルド＆リリース.setting.bat
    • ビルド環境などを設定するファイル
  • template (ディレクトリ)
    • テンプレートフォルダ。EXEやREADMEを入れておく

内容

@ビルド＆リリース.bat
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

@echo off

cd /d "%~dp0"

rem 設定ファイル読み込み
call "%~dpn0.setting.bat"

if exist "%TEMPDIR%" pause && exit
mkdir "%TEMPDIR%"

if exist "%OUTPUT%.3" rd /s /q "%OUTPUT%.3"
if exist "%OUTPUT%.2" move "%OUTPUT%.2" "%OUTPUT%.3"
if exist "%OUTPUT%.1" move "%OUTPUT%.1" "%OUTPUT%.2"
if exist "%OUTPUT%"   move "%OUTPUT%" "%OUTPUT%.1"


echo [---------- テンプレートコピー ----------]
xcopy "template" "%TEMPDIR%\out\" /E

echo [---------- 吉里吉里のコンパイル ----------]
xcopy "%PRJ%" "%TEMPDIR%\data\" /E

call :MOVE_AND_BUILD bgimage
call :MOVE_AND_BUILD bgm
call :MOVE_AND_BUILD fgimage
call :MOVE_AND_BUILD sound
call :MOVE_AND_BUILD video

call "%RELEASER%" "%TEMPDIR%\data" -out "%TEMPDIR%\out\data.xp3" -rpf "%PRJ%\default.rpf" -nowriterpf -go

echo [---------- あとしまつ ----------]
xcopy "%TEMPDIR%\out" "%OUTPUT%\" /E /Y
rd /s /q "%TEMPDIR%"


exit

:MOVE_AND_BUILD
	echo %1
	move "%TEMPDIR%\data\%1" "%TEMPDIR%\%1"
	call "%RELEASER%" "%TEMPDIR%\%1" -out "%TEMPDIR%\out\%1.xp3" -rpf "%PRJ%\default.rpf" -nowriterpf -go
exit /b
@ビルド＆リリース.setting.bat
1
2
3
4
5

set PRJ=..\data
set TEMPDIR=%TMP%\kirikiribuild.tmp.%RANDOM%
set OUTPUT=out
set RELEASER=C:\software\kr2_232\kirikiri2\tools\krkrrel.exe
template (ディレクトリ)


out

ちなみに、ビルド後はこんな感じ


解説

「@ビルド＆リリース.bat」を読めばだいたいわかると思うので割愛…